ESP32-CAM with OV7725 VGA Camera and GC9A01 Display

Pinout – GC9A01 Display:

• GC9A01 GND -> ESP32-CAM GND
• GC9A01 VCC -> ESP32-CAM 3.3V
• GC9A01 SCL-> ESP32-CAM GPIO 14
• GC9A01 SDA -> ESP32-CAM GPIO 13
• GC9A01 RES -> ESP32-CAM GPIO 4
• GC9A01 DC -> ESP32-CAM GPIO 12
• GC9A01 CS -> ESP32-CAM GPIO 2
• GC9A01 BLK -> [not connected]

Pinout – FTDI Adapter:

• ESP32-CAM GND -> FTDI GND
• ESP32-CAM 5V -> FTDI VCC (note: the voltage jumper on the adapter should be to the 5V pin)
• ESP32-CAM UOR -> FTDI TX
• ESP32-CAM UOT -> FTDI RX

#include "esp_camera.h"
#include <TFT_eSPI.h> // Hardware-specific library
#include <SPI.h>

#define CAMERA_MODEL_AI_THINKER

#define PWDN_GPIO_NUM     32
#define RESET_GPIO_NUM    -1
#define XCLK_GPIO_NUM      0
#define SIOD_GPIO_NUM     26
#define SIOC_GPIO_NUM     27
#define Y9_GPIO_NUM       35
#define Y8_GPIO_NUM       34
#define Y7_GPIO_NUM       39
#define Y6_GPIO_NUM       36
#define Y5_GPIO_NUM       21
#define Y4_GPIO_NUM       19
#define Y3_GPIO_NUM       18
#define Y2_GPIO_NUM        5
#define VSYNC_GPIO_NUM    25
#define HREF_GPIO_NUM     23
#define PCLK_GPIO_NUM     22

TFT_eSPI tft = TFT_eSPI();       // Invoke custom library
TFT_eSprite spr = TFT_eSprite(&tft);

camera_config_t config;

uint16_t *scr;

This section of code includes all the libraries necessary for the display and the camera, followed with all of the pin definitions.

The global variables and constructors are below. A sprite is created to speed up the display.

void setup() {

  Serial.begin(115200);

  tft.init();
  tft.setRotation(0);
  tft.fillScreen(TFT_BLACK);
  scr = (uint16_t*)spr.createSprite(240, 240);

  config.ledc_channel = LEDC_CHANNEL_0;
  config.ledc_timer = LEDC_TIMER_0;
  config.pin_d0 = Y2_GPIO_NUM;
  config.pin_d1 = Y3_GPIO_NUM;
  config.pin_d2 = Y4_GPIO_NUM;
  config.pin_d3 = Y5_GPIO_NUM;
  config.pin_d4 = Y6_GPIO_NUM;
  config.pin_d5 = Y7_GPIO_NUM;
  config.pin_d6 = Y8_GPIO_NUM;
  config.pin_d7 = Y9_GPIO_NUM;
  config.pin_xclk = XCLK_GPIO_NUM;
  config.pin_pclk = PCLK_GPIO_NUM;
  config.pin_vsync = VSYNC_GPIO_NUM;
  config.pin_href = HREF_GPIO_NUM;
  config.pin_sscb_sda = SIOD_GPIO_NUM;
  config.pin_sscb_scl = SIOC_GPIO_NUM;
  config.pin_pwdn = PWDN_GPIO_NUM;
  config.pin_reset = RESET_GPIO_NUM;
  config.xclk_freq_hz = 20000000;
  config.frame_size = FRAMESIZE_240X240;
  config.pixel_format = PIXFORMAT_RGB565; 
  config.grab_mode = CAMERA_GRAB_WHEN_EMPTY;
  config.fb_location = CAMERA_FB_IN_PSRAM;    
  config.jpeg_quality = 12;
  config.fb_count = 1;

  esp_err_t err = esp_camera_init(&config);

  sensor_t * s = esp_camera_sensor_get();
  s->set_brightness(s, -1);     // -2 to 2   //changed from 0 to -1
  s->set_contrast(s, -2);       // -2 to 2   //changed from 0 to -2
  s->set_saturation(s, 0);     // -2 to 2
  s->set_special_effect(s, 0); // 0 to 6 (0 - No Effect, 1 - Negative, 2 - Grayscale, 3 - Red Tint, 4 - Green Tint, 5 - Blue Tint, 6 - Sepia)
  s->set_whitebal(s, 1);       // 0 = disable , 1 = enable
  s->set_awb_gain(s, 1);       // 0 = disable , 1 = enable    
  s->set_wb_mode(s, 0);        // 0 to 4 - if awb_gain enabled (0 - Auto, 1 - Sunny, 2 - Cloudy, 3 - Office, 4 - Home)
  s->set_exposure_ctrl(s, 1);  // 0 = disable , 1 = enable    
  s->set_aec2(s, 0);           // 0 = disable , 1 = enable
  s->set_ae_level(s, 0);       // -2 to 2    
  s->set_aec_value(s, 300);    // 0 to 1200
  s->set_gain_ctrl(s, 1);      // 0 = disable , 1 = enable
  s->set_agc_gain(s, 0);       // 0 to 30
  s->set_gainceiling(s, (gainceiling_t)0);  // 0 to 6
  s->set_bpc(s, 0);            // 0 = disable , 1 = enable
  s->set_wpc(s, 1);            // 0 = disable , 1 = enable    
  s->set_raw_gma(s, 1);        // 0 = disable , 1 = enable
  s->set_lenc(s, 1);           // 0 = disable , 1 = enable
  s->set_hmirror(s, 0);        // 0 = disable , 1 = enable
  s->set_vflip(s, 0);          // 0 = disable , 1 = enable
  s->set_dcw(s, 1);            // 0 = disable , 1 = enable
  s->set_colorbar(s, 0);       // 0 = disable , 1 = enable

  tft.setTextColor(TFT_WHITE);
  tft.drawString("Loading...", 105, 105, 2);
  delay(1000);

}

The setup function begins serial communications. The serial monitor is simply for returning the frame time in milliseconds. Therefore, can be deleted with no consequence.

The display and the sprite are initialised.

The camera pins are configured as well as many sensor parameters.

Have a play with the settings. I’ve found that reducing the contrast to -2 helps to bring the colours out.

However, there is still a strange colour and pulsing of brightness. I’ve played with a few of the other settings to no avail.

void loop() {

  //take picture
  camera_fb_t  * fb = NULL;
  fb = esp_camera_fb_get();
  unsigned long initalTime = millis();

  for (size_t i = 0; i < 57600; i++) {    //240x240px = 57600
    //create 16 bit colour from two bytes. 
    byte first_byte = fb->buf[i * 2];
    byte second_byte = fb->buf[i * 2 + 1];
    scr[i] = (second_byte << 8) + first_byte;   
  }

  spr.pushSprite(0,0);
  unsigned long frameTime = millis() - initalTime;
  Serial.print("Frame time(ms) = "); Serial.println(frameTime);
  esp_camera_fb_return(fb);   //return the frame buffer back to the driver for reuse

}

The loop is short and sweet; basically capturing a frame from the camera sensor.

The camera and display both use 240×240 pixels in 16-bit colour, so the ‘for’ loop takes two bytes from the frame buffer, swaps them around and places it in a display buffer.

The display buffer is then written to the display, the camera frame buffer is deleted and the process starts again.